Script reference

main()
{
    PDebug("Hello");
}

// This example adds the value of field 1 and 2 and writes the sum to field 3
// The value of field 3 is updated every 500ms (twice per second)
 
main()
{
    SetTickInterval(500);       // Make sure the @Tick function is called twice per second
}
 
@Tick(uptime)
{
    new f1, f2;             // declare local variables
 
    f1 = GetField(1);       // set f1 to the value of field 1
    f2 = GetField(2);       // set f2 to the value of field 2
 
    SetField(3, f1+f2);     // set the value of field 3 with the sum of f1 and f2
}

// A simple demo program, counting down from 100 to 50, and then starts over
 
new myCounter;                  // Declare a 'global' variable
 
main()                          // The main() function will run on startup, once
{
    SetTickInterval(1000);      // Make sure the @Tick function is called once every 1000ms (1s)
    myCounter = 100;            // Initialize the counter with value 100
}
 
@Tick(uptime)                   // The @Tick function will be called once per second
{
    myCounter = myCounter - 1;  // Count down the counter with 1
 
    if(myCounter <= 50) {       // If we reached 50 (or lower)
        myCounter = 100         // ..then set it back to 100
    }
 
    SetField(1, myCounter);     // Update field 1 with the counter value
}

new @Speed;
 
main()
{
    SetTickInterval(5000);  // Update every 5s (5000ms)
}
 
@Tick(uptime)
{
    new Float:temp, Float:diff; // Declare "float" variables to handle fractions
    new sp = 0;                 // Use sp to find the resulting speed
 
    temp = GetFieldFloat(1);    // Fetch the current temperature from Field 1
    diff = temp - 20.5;         // 20.5 is our setpoint. diff is the differece
 
    if(diff > 0.0) {            // Over setpoint?
        SetOutput(1, 100);      // ..yes, so enable low speed
        sp++;                   // count up our speed result
    }
    else
        SetOutput(1, 0);        // ..no, so shut off
 
    if(diff > 2.0) {            // 2 degrees or more over setpoint?
        SetOutput(2, 100);      //..yes, so enable mid-speed
        sp++;                   // count up our speed result
    }
    else
        SetOutput(2, 0);
 
    if(diff > 6.0) {            // 6 degrees or more over setpoint?
        SetOutput(3, 100);      //..yes, so run full speed
        sp++;                   // count up our speed result
    }
    else
        SetOutput(3, 0);
 
    @Speed = sp;                // Make the speed available to expressions as "@Speed".
}

  new count = 0;
 
  main()
  {
    SetTickInterval(100);   // set tick interval to 100ms (0.1s)
    state WAITING;          // start in the waiting mode
  }
 
  @Tick(uptime) <WAITING>
  {
     if( GetField(1) < 100 )  // condition to start up the process
        state IGNITION;
  }
 
// ***** the IGNITION state
 
  entry() <IGNITION>
  {
     SetOutput(1, 100);       // Turn on the ignition switch
     count = 0;
  }
 
  @Tick(uptime) <IGNITION>
  {
     if( GetField(2) > 100 )  // Did the engine start?
        state RUNNING;        // yes - we're running
 
     if(count++ > 50)
        state WAITING;        // didn't start in 5s? Give up and go back to waiting.
  }
 
  exit() <IGNITION>
  {
     SetOutput(1, 0);         // Turn the ignition switch off
  }
 
// ***** the RUNNING state
 
  @Tick(uptime) <RUNNING>
  {
     if( GetField(2) < 100 )  // Check if the engine stopped
        state WAITING;        // ..go back to waiting
  }